nixos/home/modules/tmux-sessionizer.nix

{ config, lib, pkgs, ... }:

let
  inherit (lib) getExe getExe';

  cfg = config.snowhawk.tmux.sessionizer;
  tmuxCfg = config.snowhawk.tmux;

  enable = cfg.enable && tmuxCfg.enable;
in
{
  options = {
    snowhawk.tmux.sessionizer = {
      enable = lib.mkEnableOption "tmux-sessionizer home-manager module";

      paths = lib.mkOption {
        type = with lib.types; listOf str;
        description = ''
          list of paths to select with tmux-sessionizer
        '';
        default = [ ];
        example = [
          "~"
          "~/projects"
          "~/src"
        ];
      };

      pkg = lib.mkOption {
        type = lib.types.package;
        description = ''
          tmux-sessionizer binary package
        '';
      };
    };
  };

  config = lib.mkIf enable {

    snowhawk.tmux.sessionizer.pkg =
      let
        tmux = getExe pkgs.tmux;
        pgrep = getExe' pkgs.procps "pgrep";
        basename = getExe' pkgs.coreutils "basename";
        tr = getExe' pkgs.coreutils "tr";
        fzf = getExe pkgs.fzf;
        find = getExe pkgs.findutils;
      in
      lib.mkDefault (pkgs.writeShellScriptBin "tmux-sessionizer" ''
        if [[ $# -eq 1 ]]; then
          selected=$1
        else
          selected=$(${find} -L ${lib.concatStringsSep " " cfg.paths} -mindepth 1 -maxdepth 1 -type d | ${fzf})
        fi

        if [[ -z $selected ]]; then
          exit 0
        fi

        selected_name=$(${basename} "$selected" | ${tr} . _)
        tmux_running=$(${pgrep} tmux)

        if [[ -z $TMUX ]] && [[ -z $tmux_running ]]; then
          ${tmux} new-session -s "$selected_name" -c "$selected"
          exit 0
        fi

        if ! ${tmux} has-session -t="$selected_name" 2>/dev/null; then
          ${tmux} new-session -ds "$selected_name" -c "$selected"
        fi

        ${tmux} switch-client -t "$selected_name"
      '');

    home.packages = [ cfg.pkg ];
  };
}