tmux-sessionizer: writeShellApplication

home/modules/default.nix

@@ -19,6 +19,7 @@ in
 
   snowhawk.user.enable = lib.mkDefault true;
   snowhawk.tmux.enable = lib.mkDefault true;
+  snowhawk.tmux.sessionizer.enable = lib.mkDefault true;
   snowhawk.fish.enable = lib.mkDefault true;
   snowhawk.git.enable = lib.mkDefault true;
   snowhawk.lazygit.enable = lib.mkDefault true;

home/modules/tmux-sessionizer.nix

@@ -0,0 +1,61 @@
+{ config, lib, pkgs, ... }:
+
+let
+  cfg = config.snowhawk.tmux.sessionizer;
+  tmuxCfg = config.snowhawk.tmux;
+
+  enable = cfg.enable && tmuxCfg.enable;
+in
+{
+  options = {
+    snowhawk.tmux.sessionizer = {
+      enable = lib.mkEnableOption "tmux-sessionizer home-manager module";
+
+      pkg = lib.mkOption {
+        type = lib.types.package;
+        description = ''
+          tmux-sessionizer binary package
+        '';
+      };
+    };
+  };
+
+  config = lib.mkIf enable {
+
+    snowhawk.tmux.sessionizer.pkg =
+      lib.mkDefault
+        (pkgs.writeShellApplication {
+          name = "tmux-sessionizer";
+          runtimeInputs = with pkgs; [ tmux procps coreutils fzf findutils ];
+          text = ''
+            if [[ $# -eq 1 ]]; then
+            	selected=$1
+            else
+            	selected=$(find "$(readlink -f ~/projects)" ~/ ~/.config ~/.suckless/ -mindepth 1 -maxdepth 1 -type d | fzf)
+            fi
+
+            if [[ -z $selected ]]; then
+            	exit 0
+            fi
+
+            selected_name=$(basename "$selected" | tr . _)
+            tmux_running=$(pgrep tmux)
+
+            if [[ -z $TMUX ]] && [[ -z $tmux_running ]]; then
+            	tmux new-session -s "$selected_name" -c "$selected"
+            	exit 0
+            fi
+
+            if ! tmux has-session -t="$selected_name" 2>/dev/null; then
+            	tmux new-session -ds "$selected_name" -c "$selected"
+            fi
+
+            tmux switch-client -t "$selected_name"
+          '';
+        });
+
+    home.packages = [
+      config.snowhawk.tmux.sessionizer.pkg
+    ];
+  };
+}

home/modules/tmux.nix

@@ -2,6 +2,7 @@
 
 let
   cfg = config.snowhawk.tmux;
+  sessionizer = cfg.sessionizer;
 in
 {
   options.snowhawk.tmux = {
@@ -37,8 +38,12 @@ in
         bind '"' split-window -v -c "#{pane_current_path}"
         bind % split-window -h -c "#{pane_current_path}"
 
-        bind-key -r f run-shell "tmux neww ~/.user/scripts/tmux-sessionizer"
+        ${lib.optionalString sessionizer.enable ''bind-key -r f run-shell "tmux neww ${sessionizer.pkg}/bin/tmux-sessionizer"''}
       '';
     };
+
+    programs.fish.shellAbbrs = {
+      a = "tmux a";
+    };
   };
 }