{ config, lib, pkgs, ... }:

let
  cfg = config.snowhawk.tmux.sessionizer;
  tmuxCfg = config.snowhawk.tmux;

  enable = cfg.enable && tmuxCfg.enable;
in
{
  options = {
    snowhawk.tmux.sessionizer = {
      enable = lib.mkEnableOption "tmux-sessionizer home-manager module";

      paths = lib.mkOption {
        type = with lib.types; listOf str;
        description = ''
          list of paths to select with tmux-sessionizer
        '';
        default = [ ];
        example = [
          "~"
          "~/projects"
          "~/src"
        ];
      };

      pkg = lib.mkOption {
        type = lib.types.package;
        description = ''
          tmux-sessionizer binary package
        '';
      };
    };
  };

  config = lib.mkIf enable {

    snowhawk.tmux.sessionizer.pkg =
      let
        tmux = "${pkgs.tmux}/bin/tmux";
        pgrep = "${pkgs.procps}/bin/pgrep";
        basename = "${pkgs.coreutils}/bin/basename";
        tr = "${pkgs.coreutils}/bin/tr";
        fzf = "${pkgs.fzf}/bin/fzf";
        find = "${pkgs.findutils}/bin/find";
      in
      lib.mkDefault (pkgs.writeShellScriptBin "tmux-sessionizer" ''
        if [[ $# -eq 1 ]]; then
        	selected=$1
        else
        	selected=$(${find} -L ${lib.escapeShellArgs cfg.paths} -mindepth 1 -maxdepth 1 -type d | ${fzf})
        fi

        if [[ -z $selected ]]; then
        	exit 0
        fi

        selected_name=$(${basename} "$selected" | ${tr} . _)
        tmux_running=$(${pgrep} tmux)

        if [[ -z $TMUX ]] && [[ -z $tmux_running ]]; then
        	${tmux} new-session -s "$selected_name" -c "$selected"
        	exit 0
        fi

        if ! ${tmux} has-session -t="$selected_name" 2>/dev/null; then
        	${tmux} new-session -ds "$selected_name" -c "$selected"
        fi

        ${tmux} switch-client -t "$selected_name"
      '');

    home.packages = [
      config.snowhawk.tmux.sessionizer.pkg
    ];
  };
}