76 lines
1.8 KiB
Nix
76 lines
1.8 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
let
|
|
inherit (lib) getExe;
|
|
|
|
cfg = config.snowhawk.tmux.sessionizer;
|
|
tmuxCfg = config.snowhawk.tmux;
|
|
|
|
enable = cfg.enable && tmuxCfg.enable;
|
|
|
|
tmux-sessionizer = pkgs.writeShellApplication {
|
|
name = "tmux-sessionizer";
|
|
runtimeInputs = with pkgs; [ tmux fzf findutils coreutils procps ];
|
|
text = ''
|
|
if [[ $# -eq 1 ]]; then
|
|
selected=$1
|
|
else
|
|
selected=$(find -L ${lib.concatStringsSep " " cfg.paths} -mindepth 1 -maxdepth 1 -type d \
|
|
| fzf --tmux center --preview="ls {} --color || true")
|
|
fi
|
|
|
|
if [[ -z $selected ]]; then
|
|
exit 0
|
|
fi
|
|
|
|
selected_name=$(basename "$selected" | tr . _)
|
|
tmux_running=$(pgrep tmux)
|
|
|
|
if [[ -z $TMUX ]] && [[ -z $tmux_running ]]; then
|
|
tmux new-session -s "$selected_name" -c "$selected"
|
|
exit 0
|
|
fi
|
|
|
|
if ! tmux has-session -t="$selected_name" 2>/dev/null; then
|
|
tmux new-session -ds "$selected_name" -c "$selected"
|
|
fi
|
|
|
|
tmux switch-client -t "$selected_name"
|
|
'';
|
|
};
|
|
in
|
|
{
|
|
options.snowhawk.tmux.sessionizer = {
|
|
enable = lib.mkEnableOption "tmux-sessionizer home-manager module";
|
|
|
|
paths = lib.mkOption {
|
|
type = with lib.types; listOf str;
|
|
description = ''
|
|
list of paths to select with tmux-sessionizer
|
|
'';
|
|
default = [ ];
|
|
example = [
|
|
"~"
|
|
"~/projects"
|
|
"~/src"
|
|
];
|
|
};
|
|
|
|
package = lib.mkOption {
|
|
type = lib.types.package;
|
|
default = tmux-sessionizer;
|
|
description = ''
|
|
tmux-sessionizer binary package
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = lib.mkIf enable {
|
|
home.packages = [ cfg.package ];
|
|
|
|
programs.tmux.extraConfig = ''
|
|
bind-key -r f run-shell "tmux neww ${getExe cfg.package}"
|
|
'';
|
|
};
|
|
}
|